Index: /issm/trunk-jpl/ar-lib
===================================================================
--- /issm/trunk-jpl/ar-lib	(revision 11431)
+++ /issm/trunk-jpl/ar-lib	(revision 11431)
@@ -0,0 +1,1 @@
+link /cygdrive/c/issm-uci/trunk-jpl/externalpackages/automake/install/share/automake-1.11/ar-lib
Index: /issm/trunk-jpl/configure.ac
===================================================================
--- /issm/trunk-jpl/configure.ac	(revision 11430)
+++ /issm/trunk-jpl/configure.ac	(revision 11431)
@@ -6,11 +6,12 @@
 AM_INIT_AUTOMAKE
 AC_PROG_RANLIB
-AC_PROG_CC([gcc icl])
+AC_PROG_CC([gcc icl cccl cl])
 AC_PROG_CPP
-AC_PROG_CXX([g++ icl])
+AC_PROG_CXX([g++ icl cccl cl])
 AC_PROG_F77([ifort g77 gfortran])
 AC_F77_LIBRARY_LDFLAGS
 AM_PROG_CC_C_O
 AC_PATH_XTRA
+AM_PROG_AR
 ISSM_OPTIONS
 AC_CONFIG_FILES([Makefile
Index: /issm/trunk-jpl/m4/ar-lib.m4
===================================================================
--- /issm/trunk-jpl/m4/ar-lib.m4	(revision 11431)
+++ /issm/trunk-jpl/m4/ar-lib.m4	(revision 11431)
@@ -0,0 +1,61 @@
+##                                                          -*- Autoconf -*-
+# Copyright (C) 2011 Free Software Foundation, Inc.
+#
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# serial 1
+
+# AM_PROG_AR([ACT-IF-FAIL])
+# -------------------------
+# Try to determine the archiver interface, and trigger the ar-lib wrapper
+# if it is needed.  If the detection of archiver interface fails, run
+# ACT-IF-FAIL (default is to abort configure with a proper error message).
+AC_DEFUN([AM_PROG_AR],
+[AC_BEFORE([$0], [LT_INIT])dnl
+AC_BEFORE([$0], [AC_PROG_LIBTOOL])dnl
+AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
+AC_REQUIRE_AUX_FILE([ar-lib])dnl
+AC_CHECK_TOOLS([AR], [ar lib "link -lib"], [false])
+: ${AR=ar}
+
+AC_CACHE_CHECK([the archiver ($AR) interface], [am_cv_ar_interface],
+  [am_cv_ar_interface=ar
+   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int some_variable = 0;]])],
+     [am_ar_try='$AR cru libconftest.a conftest.$ac_objext >&AS_MESSAGE_LOG_FD'
+      AC_TRY_EVAL([am_ar_try])
+      if test "$ac_status" -eq 0; then
+        am_cv_ar_interface=ar
+      else
+        am_ar_try='$AR -NOLOGO -OUT:conftest.lib conftest.$ac_objext >&AS_MESSAGE_LOG_FD'
+        AC_TRY_EVAL([am_ar_try])
+        if test "$ac_status" -eq 0; then
+          am_cv_ar_interface=lib
+        else
+          am_cv_ar_interface=unknown
+        fi
+      fi
+      rm -f conftest.lib libconftest.a
+     ])
+   ])
+
+case $am_cv_ar_interface in
+ar)
+  ;;
+lib)
+  # Microsoft lib, so override with the ar-lib wrapper script.
+  # FIXME: It is wrong to rewrite AR.
+  # But if we don't then we get into trouble of one sort or another.
+  # A longer-term fix would be to have automake use am__AR in this case,
+  # and then we could set am__AR="$am_aux_dir/ar-lib \$(AR)" or something
+  # similar.
+  AR="$am_aux_dir/ar-lib $AR"
+  ;;
+unknown)
+  m4_default([$1],
+             [AC_MSG_ERROR([could not determine $AR interface])])
+  ;;
+esac
+AC_SUBST([AR])dnl
+])